·您当前的位置:首页 > 技术教程 > AS2与AS3技术 >

[AS3]as3.0版BASE64加密与解密类(编码与解码类)完整版

时间:2012-12-19 15:31cnblogs.com
[AS3]as3.0版BASE64加密与解密类(编码与解码类)完整版,as3加密,as3解密,编码和解码字符串用法

[AS3]as3.0版BASE64加密与解密类(编码与解码类)完整版

  1. import com.dynamicflash.utils.Base64;       
  2. //CuPlayer提示:编码和解码字符串      
  3. var source:String = "Hello, world";       
  4. var encoded:String = Base64.encode(source);       
  5. trace(encoded);       
  6.       
  7. var decoded:String = Base64.decode(encoded);       
  8. trace(decoded);      
  9.  
  10. //CuPlayer提示:编码和解码ByteArray      
  11. var obj:Object= {name:"Dynamic Flash",url:"http://dynamicflash.com"};    
  12. var source:ByteArray = new ByteArray();    
  13. source.writeObject(obj);    
  14.    
  15. var encoded:String = Base64.encodeByteArray(source);    
  16. trace(encoded);    
  17.    
  18. var decoded:ByteArray = Base64.decodeToByteArray(encoded);    
  19. obj = decoded.readObject();    
  20. trace(obj.name + "(" + obj.url + ")");   

 

  1. //CuPlayer提示:Base64类代码: 
  2. package com.dynamicflash.util{    
  3.    
  4.     import flash.utils.ByteArray;    
  5.         
  6.     public class Base64 {    
  7.             
  8.         private static const BASE64_CHARS:String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/=";    
  9.    
  10.         public static const version:String = "1.0.0";    
  11.    
  12.         public static function encode(data:String):String {    
  13.             // Convert string to ByteArray    
  14.             var bytes:ByteArray = new ByteArray();    
  15.             bytes.writeUTFBytes(data);    
  16.                 
  17.             // Return encoded ByteArray    
  18.             return encodeByteArray(bytes);    
  19.         }    
  20.             
  21.         public static function encodeByteArray(data:ByteArray):String {    
  22.             // Initialise output    
  23.             var output:String = "";    
  24.                 
  25.             // Create data and output buffers    
  26.             var dataBuffer:Array;    
  27.             var outputBuffer:Array = new Array(4);    
  28.                 
  29.             // Rewind ByteArray    
  30.             data.position = 0;    
  31.                 
  32.             // while there are still bytes to be processed    
  33.             while (data.bytesAvailable > 0) {    
  34.                 // Create new data buffer and populate next 3 bytes from data    
  35.                 dataBuffer = new Array();    
  36.                 for (var i:uint = 0; i < 3 && data.bytesAvailable > 0; i++) {    
  37.                     dataBuffer[i] = data.readUnsignedByte();    
  38.                 }    
  39.                     
  40.                 // Convert to data buffer Base64 character positions and     
  41.                 // store in output buffer    
  42.                 outputBuffer[0] = (dataBuffer[0] & 0xfc) >> 2;    
  43.                 outputBuffer[1] = ((dataBuffer[0] & 0x03) << 4) | ((dataBuffer[1]) >> 4);    
  44.                 outputBuffer[2] = ((dataBuffer[1] & 0x0f) << 2) | ((dataBuffer[2]) >> 6);    
  45.                 outputBuffer[3] = dataBuffer[2] & 0x3f;    
  46.                     
  47.                 // If data buffer was short (i.e not 3 characters) then set    
  48.                 // end character indexes in data buffer to index of '=' symbol.    
  49.                 // This is necessary because Base64 data is always a multiple of    
  50.                 // 4 bytes and is basses with '=' symbols.    
  51.                 for (var j:uint = dataBuffer.length; j < 3; j++) {    
  52.                     outputBuffer[j + 1] = 64;    
  53.                 }    
  54.                     
  55.                 // Loop through output buffer and add Base64 characters to     
  56.                 // encoded data string for each character.    
  57.                 for (var k:uint = 0; k < outputBuffer.length; k++) {    
  58.                     output += BASE64_CHARS.charAt(outputBuffer[k]);    
  59.                 }    
  60.             }    
  61.                 
  62.             // Return encoded data    
  63.             return output;    
  64.         }    
  65.             
  66.         public static function decode(data:String):String {    
  67.             // Decode data to ByteArray    
  68.             var bytes:ByteArray = decodeToByteArray(data);    
  69.                 
  70.             // Convert to string and return    
  71.             return bytes.readUTFBytes(bytes.length);    
  72.         }    
  73.             
  74.         public static function decodeToByteArray(data:String):ByteArray {    
  75.             // Initialise output ByteArray for decoded data    
  76.             var output:ByteArray = new ByteArray();    
  77.                 
  78.             // Create data and output buffers    
  79.             var dataBuffer:Array = new Array(4);    
  80.             var outputBuffer:Array = new Array(3);    
  81.    
  82.             // While there are data bytes left to be processed    
  83.             for (var i:uint = 0; i < data.length; i += 4) {    
  84.                 // Populate data buffer with position of Base64 characters for    
  85.                 // next 4 bytes from encoded data    
  86.                 for (var j:uint = 0; j < 4 && i + j < data.length; j++) {    
  87.                     dataBuffer[j] = BASE64_CHARS.indexOf(data.charAt(i + j));    
  88.                 }    
  89.                     
  90.                 // Decode data buffer back into bytes    
  91.                 outputBuffer[0] = (dataBuffer[0] << 2) + ((dataBuffer[1] & 0x30) >> 4);    
  92.                 outputBuffer[1] = ((dataBuffer[1] & 0x0f) << 4) + ((dataBuffer[2] & 0x3c) >> 2);            
  93.                 outputBuffer[2] = ((dataBuffer[2] & 0x03) << 6) + dataBuffer[3];    
  94.                     
  95.                 // Add all non-padded bytes in output buffer to decoded data    
  96.                 for (var k:uint = 0; k < outputBuffer.length; k++) {    
  97.                     if (dataBuffer[k+1] == 64) break;    
  98.                     output.writeByte(outputBuffer[k]);    
  99.                 }    
  100.             }    
  101.                 
  102.             // Rewind decoded data ByteArray    
  103.             output.position = 0;    
  104.                 
  105.             // Return decoded data    
  106.             return output;    
  107.         }    
  108.             
  109.         public function Base64() {    
  110.             throw new Error("Base64 class is static container only");    
  111.         }    
  112.     }    

 

热门文章推荐

请稍候...

保利威视云平台-轻松实现点播直播视频应用

酷播云数据统计分析跨平台播放器