[AS3]as3下p2p NetGroup聊天代码示例(rtmfp协议示例)(3)

第六步：建立界面

    <s:TextArea left="10" right="10" top="10" bottom="40" id="txtHistory"/> 
    <s:TextInput x="10" id="txtUser" text="{user}" bottom="10"/> 
    <s:TextInput left="145" right="88" id="txtMessage" bottom="10" enter="sendMessage()"/> 
    <s:Button label="Send" click="sendMessage()" enabled="{connected}" bottom="10" right="10"/>  
 
以下是完整的代码： 
 
<fx:Script> 
  <![CDATA[ 
   private const SERVER:String = "rtmfp://p2p.rtmfp.net/"; 
   private const DEVKEY:String = "d8c6d5b18ddf65bf1529fd4c-c98c749416ce"; 
   private var nc:NetConnection; 
   private var netGroup:NetGroup; 
   [Bindable] 
   private var connected:Boolean = false; 
   [Bindable] 
   private var user:String; 
    
   private function connect():void{ 
     nc = new NetConnection(); 
     nc.addEventListener(NetStatusEvent.NET_STATUS,netStatus); 
     nc.connect(SERVER+DEVKEY); 
   }    
    
   internal function netStatus(evt:NetStatusEvent):void{ 
      switch(evt.info.code){ 
        case "NetConnection.Connect.Success": 
      setupGroup(); 
      break; 
     case "NetGroup.Connect.Success": 
      connected = true; 
      break; 
     case "NetGroup.Posting.Notify": 
      receiveMessage(evt.info.message); 
      break; 
     
      } 
   } 
    
   private function setupGroup():void{ 
     var gorupspec:GroupSpecifier = new GroupSpecifier("myGroup/g1"); 
     gorupspec.serverChannelEnabled = true; 
     gorupspec.postingEnabled = true; 
     netGroup = new NetGroup(nc,gorupspec.groupspecWithAuthorizations()); 
     netGroup.addEventListener(NetStatusEvent.NET_STATUS,netStatus); 
     user = "user"+Math.round(Math.random() * 1000); 
   } 
    
   private function sendMessage():void{ 
     var message:Object = new Object(); 
     message.sender = netGroup.convertPeerIDToGroupAddress(nc.nearID); 
     message.user = txtUser.text; 
     message.text = txtMessage.text; 
     netGroup.post(message); 
     receiveMessage(message); 
     txtMessage.text = ""; 
   } 
    
   internal function receiveMessage(message:Object):void{ 
    write(message.user+": "+message.text); 
   } 
   private function write(txt:String):void{ 
    txtHistory.text += txt+"\n"; 
   } 
    
  ]]> 
 </fx:Script>